#Notice to the user:
# The latest version of toolbox may be obtained in one of two ways:
#	1) email me (dehall@mailhost.ecn.uoknor.edu)
# 	2) msg my bot (HAL1000)
#
# This particular version is intended for 2.2 clients.  There is a
# version out there for pre7 clients (also obtainable in the previous
# two ways).
#
# I would like to thank the following for encouragement and ideas:
#   WildThang, Scissors, M_Force, Tychy, DemoN, THRUD 
#
# I have probably forgotten somebody and to them I appologize.
#
# Well, here it is....oh, one final thing, this version packaged
# on,
#     29 April 93.  
#                    (I come out with a new refinement about once a
# month so that should help ya decide on if you have the latest :)

echo Loading DaveMan's ToolBox version 5.1b for 2.2 Clients...
echo  Packages are as follows:
echo          DaveMan's Aboot     Series 3
echo          DaveMan's Anti2     Series 1
echo          DaveMan's Ban2      Series 1
echo          DaveMan's Botkill   Series 2
echo          DaveMan's Mass      Series 2
echo          DaveMan's Pignore   Series 2
echo          DaveMan's Quiet     Series 2

#============================================================================
# DaveMan's Aboot                      4/4/93 
#
# Description:  An auto kick/ban by login activated by using only a nick.
#
# Usage:  /aboot nick              - kick/ban nick 
#         /aboot                   - display targetted logins
#         /noaboot nick            - remove nick from kick/ban list 
#         /noaboot                 - clear all logins from kick/ban list
#
# Note:  Requires "DaveMan's Remove" to run correctly.  Additionally, 
#        running "DaveMan's Ban" enables the script to remove bans placed
#        On a targeted login once removed from the kick/ban list.
#-----------------------------------------------------------------------------

alias aboot {
	if ([$0]){
		^userhost $0 -cmd ^assign abtarg $abtarg $$3@*
   ^userhost $0 -cmd ^assign daban *!*$$3*@* *!*$$3*@*$$4* *!*$$3@*$$4
		echo *** TARGETING $0 ***
		kick $C $0
		mode $C +bbb $daban
		}
		{
		echo *** TARGETING THE FOLLOWING ***
		vlist $abtarg
		}
	}


alias noaboot {
	if ([$0]){
		^userhost $0 -cmd ^assign abrm $$3@*
		wait
		^remove $abrm abtarg
		echo *** REMOVING $0 FROM TARGET LIST ***
		^unban $0}
		{
		^assign -abtarg
		echo *** TARGETING SYSTEMS DEACTIVATED ***}
	}


alias vlist if ([$0]){echo     $0 ;vlist $1-}{echo *** END OF LIST ***}


on #-join 10 * if (rmatch($userhost() $abtarg)){
	userhost $0 -cmd ^assign daban *!*$$3*@* *!*$$3*@*$$4* *!*$$3@*$$4*
	kick $1 $0
	mode $1 +bbb $daban
	}
	

#==================================================================
# DaveMan's Anti2 for 2.2 clients                4/15/93
#
# Description: Anti mass  kick/deop/ban routine that does not kick
#              you, nor does it require /on kick.
#
# Usage:  Just /load anti2
#-----------------------------------------------------------------

alias getem if ([$1]!=N){
	kick $0 $1
	msg $0 *** MASS KICK/BAN/DEOP PROTECTION ACTIVATED ***
	msg $1 *** MASS KICK/BAN/DEOP PROTECTION ACTIVATED ***
	echo *** MASS KICK/BAN/DEOP PROTECTION ACTIVATED ***
	@ mcount = 0
	}

on #-mode 100 "% % %-%o% *" if (userhost()==last){
		@ mcount = mcount + 12 
		if (mcount > 50){getem $1 $0}
		}
		{
		@ last = [$userhost()] 
		if (mcount > 2){@ mcount = mcount - 4}
		}
	

on #-mode 100 "% % %+%b% *" if (userhost()==last){
		@ mcount = mcount + 10 
		if (mcount > 50){getem $1 $0}
		}
		{
		@ last = [$userhost()]
		if (mcount > 4){@ mcount = mcount - 4}
		}


on #-raw_irc 100 "% KICK *" {
	@ host = [$0]
	@ tst = 0
	@ cnt = 0
	@ host = [$right(${@host-1+index(! $host)} $host)]
	if (host==last){
		@ mcount = mcount + 15
		if (mcount > 50){getem $2 $left($index(! $0) $0)}
		}
		{
		@ last = [$host]
		if (mcount > 8){@ mcount = mcount - 8}
		}
	}

on #-public 100 * @ mcount = mcount - 1
on #-join 100 * @ mcount = mcount - 8


#=======================================================================
# DaveMan's Ban2 for 2.2 clients       - 4/15/93
#
# Discription: Easy to use aliases to ban/unban by login given a nick.
# 
# Usage:  
#	/BAN				- displays current channel bans
#	/BAN nick			- bans nick
#	/UNBAN				- unbans you
#       /UNBAN nick			- unbans nick	
#       /CLEARBAN  			- clears a channel of bans
#------------------------------------------------------------------------

alias ban if ([$0]){
	userhost $0 -cmd rndstring *!$$3@$$4 dabana
	userhost $0 -cmd rndstring *!$$3@$$4 dabanb
	wait
	mode $C +bbb $dabana $dabanb $0!*@*
	^assign -dabana
	^assign -dabanb
	}
	{
	mode $C +b
	}

alias unban {
	if ([$0]){
		userhost $0 -cmd ^assign dabana $$0!$$3@$$4
		}
		{
		userhost $N -cmd ^assign dabana $$0!$$3@$$4
		}
	^on ^367 * if (rmatch($dabana $2)){@ blist = [$blist $2]}
	^assign cnt 0
	^mode $C +b
	wait

	while (word($cnt $blist)){
	    	ub2 $word($cnt $blist) $word(${cnt+1} $blist)
		@ cnt = cnt + 2
		}

	^assign -blist
	^assign -cnt
	^on ^367 -*
	}

alias clearban {
	^on ^367 * {@ blist = [$blist $2]}
	^assign cnt 0
	^mode $C +b
	wait
	
	while (word($cnt $blist)){
		ub2 $word($cnt $blist) $word(${cnt+1} $blist)
		@ cnt = cnt + 2
		}
	
	^assign -blist
	^assign -cnt
	^on ^367 -*
	}

# UB2
# Unbans 2 at a time...cant get 3 to work for some wierd reason...

alias ub2 {
	if ([$1]!=[]){mode $C -bb $0-1}
	if (([$0]!=[])&&([$1]==[])){mode $C -b $0}
	}

# RNDSTRING
# This alias returns a string with ?'s randomly replacing certain characters
#...great for ban aliases.


alias rndstring {
	@ cnt = 0
	while (mid($cnt 1 $0)!=[]){
		@ rn = rand(10)
if ((mid($cnt 1 $0)!=[!])&&(mid($cnt 1 $0)!=[@])&&(mid($cnt 1 $0)!=[*])){
		   if (rn>7){@ temp = [$temp?]}{@ temp = [$temp$mid($cnt 1 $0)]}
		   }
		   {
		   @ temp = [$temp$mid($cnt 1 $0)]
		   }
		@ cnt = cnt + 1
		}	
	^assign $1 $temp
	^assign -temp
	}


#===============================================================================
#DaveMan's Botkill                            4/4/93
#
#Description:  A script to find/deop/kick/ban all nicks using the same account. 
#              (In 99 cases out of 100, this means GET THE BOTS TOO!)
#
#Usage:  /botkill nick
#
#Note:  Although the bans employed by this script are simple, this is easy
#       to change with the use of any decent ban script.
#-------------------------------------------------------------------------------

alias botkill {
	if ([$0]){
		^set display off
		on #who -164 "Channel Nickname *"
		on #who -164 * {@ mlist = [$1 $mlist]}
		userhost $0 -cmd assign btarg $$3
		userhost $0 -cmd assign daban *!$$3@*$$4*
		@ mcnt = 1
		wait
		who $btarg
		wait
		set display on
		while ([$(#mlist)]>=mcnt){
			mode $C -ooo $word(${mcnt-1} $mlist) $word($mcnt $mlist) $word(${mcnt+1} $mlist)
			@ mcnt = mcnt + 3
			}
		mode $C +b $daban
		@ mcnt = 0
		while ([$(#mlist)]>mcnt){
			kick $C $word($mcnt $mlist)
			@ mcnt = mcnt + 1
			}
		^assign -mcnt
		^assign -mlist
		^assign -btarg
		}
	}


#======================================================================
#DaveMan's Mass                         4/4/93
#
# Description: Mass Deop/Op/Kick aliases that work faster than many
#              while avoiding max recursion limits.
#
# Usage: Simply...    /massop   /massdeop   /masskick
#
# Note:  Massop will not op those who already have ops.  Massdeop will
#        not deop you or anybody under your login.  Masskick will not
#        kick you or anybody under your login.
#======================================================================
alias massop {
	^set display off
 	on ^who * if (ischanop($1 $C)==0){@ mlist = [$1 $mlist]}
	on ^who "% % % user host*"
	^who $C
	wait
	@ mcnt = 1
	set display on
	while ([$(#mlist)]>=mcnt){
		mode $C +ooo $word(${mcnt-1} $mlist) $word($mcnt $mlist) $word(${mcnt+1} $mlist)
		@ mcnt = mcnt + 3
		}
	^on who -
	@ mlist = []
	}


alias massdeop {
	^set display off
	userhost $N -cmd assign mme $$3
 	on ^who * if ((ischanop($1 $C))&&(mme!=[$3])){@ mlist = [$1 $mlist]}
	on ^who "% % % user host*"
	^who $C
	wait
	@ mcnt = 1
	set display on
	while ([$(#mlist)]>=mcnt){
		mode $C -ooo $word(${mcnt-1} $mlist) $word($mcnt $mlist) $word(${mcnt+1} $mlist)
		@ mcnt = mcnt + 3
		}
	^on who -
	@ mlist = []
	}

alias masskick {
	^set display off
	userhost $N -cmd assign mme $$3
 	on ^who * if (mme!=[$3]){@ mlist = [$1 $mlist]}
	on ^who "% % % user host*"
	^who $C
	wait
	@ mcnt = 0
	set display on
	while ([$(#mlist)]>mcnt){
		kick $C $word($mcnt $mlist)
		@ mcnt = mcnt + 1
		}
	^on who -
	@ mlist = []
	}


#=============================================================================
# DaveMan's Quiet 1.1 For 2.2 Clients
#
#Description:  Script to tame the extensive mode changes seen during op wars
#              and show only those that effect you.  Useful for when you are
#              actually in a conversation!  Can be turned on and off.
#
#Usage:        /quiet          -shows mode changes that effect YOU
#              /quiet nick     -shows mode changes that effect nick
#              /noquiet        -shows all mode changes again
#============================================================================
assign qcnt 0
assign qtst 0

alias quiet {
	if ([$0]){
		^userhost $0 -cmd ^assign qli $qli $$0 $$0!$$3@$$4}
		{
		^userhost $N -cmd ^assign qli $qli $$0 $$0!$$3@$$4}
	^on ^mode *
	^on #^mode 222 * {qecho $0-}
	echo *** SILENT RUNNING ***
	}

alias noquiet {
	^assign -qli 
	^on #-mode 222 *
	^on -mode *
	echo *** SECURE FROM SILENT RUNNING ***}

alias qecho {
        while (qcnt < #qli) {
    if (rmatch($word($qcnt $qli) $0)){@ qtst = 1}
    if (rmatch($word($qcnt $qli) $3)){@ qtst = 1}
    if (rmatch($word($qcnt $qli) $4)){@ qtst = 1}
    if (rmatch($word($qcnt $qli) $5)){@ qtst = 1}
    if (rmatch($word($qcnt $qli) $6)){@ qtst = 1}
                 @ qcnt = qcnt + 1}
	if (qtst>0) {echo *** Mode change $2 $3-6 on channel $1 by $0}
        @ qtst = 0
        @ qcnt = 0
         }


#====================================================================
# Message stuff
# Misc msg alias, part mine, part unknown (got it from THRUD)
#---------------------------------------------------------------------
ON #-MSG 1000 * ^_add_msg $0 $msg_list
ON -SEND_MSG "* *" ^_add_msg $0 $msg_list

ALIAS _ADD_MSG if ([$0]==[$1]){@ msg_list = [$0 $2-10]}{@ msg_list = [$0-10]};@ msg_cnt = 0

ALIAS _GET_MSG {
     type ^U/msg $($msg_cnt) 
     @ msg_cnt = msg_cnt+1
     if ([$(#msg_list)]<msg_cnt) {@ msg_cnt = 0}
     }

ALIAS M if ([$($0)]){msg $($0) $1-}{msg $0 $1-}

BIND ^I PARSE_COMMAND /^_get_msg $msg_list


#============================================================================
# REMOVE written by DaveMan, based on concept of a script by Daemon
# removes single element from a string...used in some stuff here....
#----------------------------------------------------------------------------

alias remove {
       @ tcnt = 0
       @ temp = []
       @ $1 = [$($1) XX]
       while (word($tcnt $($1))!=[XX]){
	     if ([$0]!=word($tcnt $($1))){@ temp = [$temp $word($tcnt $($1))]}
	     @ tcnt = tcnt + 1 
	     }
       @ $1 = [$temp]
       ^assign -temp
       }

#===========================================================================
# REPEAT written by DaveMan
# Description: Name says it all...based on something I saw in THRUD's ircrc,
#              updated for pre7.
# Usage :  /repeat /command
#---------------------------------------------------------------------------

ALIAS REPEAT {
	@ b = 0
        while (b<[$0]) {
        	$1-
                @ b = b+1}
        ^assign -b}